Chip 2007 January, February, March & April/Chip-Cover-CD-2007-02.iso/Pakiet multimedia/Muzyka/Odtwarzacze muzyki/iTunes 7.0.2.16/iTunesSetup.exe/RCDATA/CABINET/iTunes.msi/Binary.Scripts.vbs

Text File | 2006-10-30 | 11KB | 355 lines

' VBScript source code
Option Explicit

' Launch condition related subroutines-----------------------------------------

Sub iTunesLaunchConditions
    PreventDowngrade
    DetectGEARDriverSetDeletion
    CheckUnsupportediPodSoftware
End Sub

Function CompareVersions(sVersion1, sVersion2)
    Dim rgExpVersionComponents
    Dim oMatches1, oMatches2
    Dim iVersion1, iVersion2
    Dim i

    On Error Resume Next
    Set rgExpVersionComponents = New RegExp
    rgExpVersionComponents.Pattern = "(\d+)\.?"
    rgExpVersionComponents.Global= True
    Set oMatches1 = rgExpVersionComponents.Execute(sVersion1)
    Set oMatches2 = rgExpVersionComponents.Execute(sVersion2)
    i = 0
    Do
        Err.Clear
        iVersion1 = 0
        iVersion2 = 0
        iVersion1 = CInt(oMatches1(i).SubMatches(0))
        iVersion2 = CInt(oMatches2(i).SubMatches(0))
        If iVersion1 < iVersion2 Then
            CompareVersions = -1
            Exit Function
        ElseIf iVersion1 > iVersion2 Then
            CompareVersions = 1
            Exit Function
        End If
        i = i + 1
    Loop While Err.number = 0
    CompareVersions = 0
End Function

Sub PreventDowngrade
    Const msiInstallStateAdvertised = 1
    Dim Installer
    Dim RelatedProducts
    Dim UpgradeCode
    Dim ProductCode
    Dim ProductVersion
    Dim ProductVersionMax
    Dim ProductVersionFound

    On Error Resume Next
    Set Installer = Session.Installer
    ProductVersion = Session.Property("ProductVersion")
    ProductVersionMax = ""
    UpgradeCode = Session.Property("UpgradeCode")
    Set RelatedProducts = Installer.RelatedProducts(UpgradeCode)
    For Each ProductCode in RelatedProducts
        If Installer.ProductState(ProductCode) = msiInstallStateAdvertised Then
            ProductVersionFound = Installer.ProductInfo(ProductCode, "Version")
        Else
            Err.Clear : ProductVersionFound = Installer.ProductInfo(ProductCode, "VersionString")
            If Err.number <> 0 Then ProductVersionFound = ""
        End If
        If CompareVersions(ProductVersionFound, ProductVersionMax) > 0 Then ProductVersionMax = ProductVersionFound
    Next
    If CompareVersions(ProductVersionMax, ProductVersion) > 0 Then
        Session.Property("BNEWERITUNESISINSTALLED") = "1"
    Else
        Session.Property("BNEWERITUNESISINSTALLED") = ""
    End If
End Sub

Sub DetectGEARDriverSetDeletion
    Dim DeleteFlag

    On Error Resume Next
    DeleteFlag = Session.Installer.RegistryValue(2,"SYSTEM\CurrentControlSet\Services\GearAspiWDM", "DeleteFlag")
    If Err.number <> 9 Then
        If IsNumeric(DeleteFlag) Then
            Session.Property("GEARASPIWDM_SERVICE_DELETED") = "#" + CStr(DeleteFlag)
        Else
            Session.Property("GEARASPIWDM_SERVICE_DELETED") = DeleteFlag
        End If
    End If
End Sub

Sub CheckUnsupportediPodSoftware
    Const msiInstallStateUnknown = -1

    If Session.Installer.ProductState("{020700E4-A96B-4769-BA56-2106150F7B98}") <> msiInstallStateUnknown Or _
        Session.Installer.ProductState("{D593BE84-013B-4221-B34C-B3767C408FAC}") <> msiInstallStateUnknown Or _
        Session.Installer.ProductState("{C062DBC7-009D-4D5E-B80E-5829650F7D24}") <> msiInstallStateUnknown Then
        Session.Property("UNSUPPORTEDIPODSOFTWARE") = "1"
    Else
        Session.Property("UNSUPPORTEDIPODSOFTWARE") = ""
    End If
End Sub

Sub FindASUInstalled
    Const msiInstallStateAdvertised = 1
    Dim Installer
    Dim RelatedProducts
    Dim UpgradeCode
    Dim ProductCode
    Dim ProductVersionMin
    Dim ProductVersionFound

    On Error Resume Next
    Set Installer = Session.Installer
    ProductVersionMin = "1.0.2"
    UpgradeCode = "{58E373E7-C6D5-4691-885F-721D3B317918}"
    Set RelatedProducts = Installer.RelatedProducts(UpgradeCode)
    If RelatedProducts.Count > 0 Then
        Session.Property("ASUWISINSTALLED") = "1"
    Else
        Session.Property("ASUWISINSTALLED") = ""
    End If
    Session.Property("OLDERASUWISINSTALLED") = ""
    For Each ProductCode in RelatedProducts
        If Installer.ProductState(ProductCode) = msiInstallStateAdvertised Then
            ProductVersionFound = Installer.ProductInfo(ProductCode, "Version")
        Else
            Err.Clear : ProductVersionFound = Installer.ProductInfo(ProductCode, "VersionString")
            If Err.number <> 0 Then ProductVersionFound = ""
        End If
        If CompareVersions(ProductVersionFound, ProductVersionMin) < 0 Then
            ProductVersionMin = ProductVersionFound
            Session.Property("OLDERASUWISINSTALLED") = "1"
        End If
    Next
End Sub

' -----------------------------------------------------------------------------

Sub CheckRebootNeeded
    Const msiRunModeMaintenance = 2
    Const msiRunModeRebootAtEnd = 6
    Const msiEvaluateConditionTrue = 1
    Dim fReboot

    On Error Resume Next
    fReboot = False
    Err.Clear : Session.Installer.RegistryValue 2,"SYSTEM\CurrentControlSet\Services\GearAspiWDM", "Reboot"
    If Err.number <> 9 Then fReboot = True
    Err.Clear : Session.Installer.RegistryValue 2,"SYSTEM\CurrentControlSet\Services\GearAspiWDM", "DeleteFlag"
    If Err.number <> 9 Then fReboot = True
    If Session.EvaluateCondition("VersionNT=500 AND &GEAR>=2") = msiEvaluateConditionTrue Then fReboot = True
    If Session.EvaluateCondition("$EnableAutoPlayRegistry>2") = msiEvaluateConditionTrue Then fReboot = True
    If fReboot Then Session.Mode(msiRunModeRebootAtEnd) = True
End Sub

Function WindowsFirewallInitialize(ByRef fwProfile)
    Dim    fwMgr
    Dim    fwPolicy
    Dim    success

    ' assume failure
    Set fwProfile = Nothing
    success = False

    On Error Resume Next
    Set fwMgr = CreateObject("HNetCfg.FwMgr")
    If IsObject(fwMgr) Then
        Set fwPolicy = fwMgr.LocalPolicy
        Set fwProfile = fwPolicy.CurrentProfile
        success = True
    End If

    ' clean up objects
    If IsObject(fwPolicy) Then Set fwPolicy = Nothing
    If IsObject(fwMgr) Then Set fwMgr = Nothing

    WindowsFirewallInitialize = success
End Function

Function WindowsFirewallAppIsEnabled(fwProfile, appPath, ByRef isEnabled)
    Dim    success
    Dim    tempResult
    Dim    fwApps
    Dim    fwApp

    ' assume failure
    success = False
    isEnabled = False

    On Error Resume Next
    ' retrieve the authorized application collection
    Set fwApps = fwProfile.AuthorizedApplications
    If IsObject(fwApps) Then
        ' attempt to retrieve the specIfied application
        Set fwApp = fwApps.Item(appPath)
        If Not IsObject(fwApp) Then
            success = True
        ' is the application enabled?
        ElseIf fwApp.Enabled Then
            isEnabled = True
            success = True
        Else
            success = True
        End If
    End If

    ' clean up objects
    If IsObject(fwApp) Then Set fwApp = Nothing
    If IsObject(fwApps) Then Set fwApps = Nothing
    WindowsFirewallAppIsEnabled = success
End Function

Function WindowsFirewallAddApp(fwProfile, appPath, appName)
    Dim    success
    Dim    appEnabled
    Dim    fwApps
    Dim    fwApp

    ' assume failure
    success = False
    appEnabled = False

    On Error Resume Next
    success = WindowsFirewallAppIsEnabled(fwProfile, appPath, appEnabled)
    If success And Not appEnabled Then
        success = False
        ' retrieve the authorized application collection
        Set fwApps = fwProfile.AuthorizedApplications
        ' create an instance of an authorized application
        Set fwApp = CreateObject("HNetCfg.FwAuthorizedApplication")
        If IsObject(fwApps) And IsObject(fwApp) Then
            Err.Clear
            ' Set the application friendly name
            fwApp.Name = appName
            ' Set the process image file name
            fwApp.ProcessImageFileName = appPath
            If Err.number = 0 Then
                ' add the application to the collection
                fwApps.Add(fwApp)
                If Err.number = 0 Then success = True
            End If
        End If
    End If

    ' clean up objects
    If IsObject(fwApp) Then    Set fwApp = Nothing
    If IsObject(fwApps) Then Set fwApps = Nothing

    WindowsFirewallAddApp = success
End Function

Function WindowsFirewallRemoveApp(fwProfile, appPath)
    Dim    success
    Dim    tempResult
    Dim    fwApps

    ' assume failure
    success = False

    On Error Resume Next
    ' retrieve the authorized application collection
    Set fwApps = fwProfile.AuthorizedApplications

    If IsObject(fwApps) Then
        Err.Clear
        ' attempt to remove the specIfied application
        fwApps.Remove appPath
        If Err.number = 0 Then success = True
    End If

    ' clean up object
    If IsObject(fwApps) Then Set fwApps = Nothing

    WindowsFirewallRemoveApp = success
End Function

Sub AddiTunesToWindowsFirewall
    Dim fwProfile
    Dim PathToiTunesExe

    WindowsFirewallInitialize fwProfile
    If IsObject(fwProfile) Then
        PathToiTunesExe = Session.Property("CustomActionData")
        WindowsFirewallRemoveApp fwProfile, PathToiTunesExe
        WindowsFirewallAddApp fwProfile, PathToiTunesExe, "iTunes"
        Set fwProfile = Nothing
    End If
End Sub

Sub RemoveiTunesFromWindowsFirewall
    Dim fwProfile
    Dim PathToiTunesExe

    WindowsFirewallInitialize fwProfile
    If IsObject(fwProfile) Then
        PathToiTunesExe = Session.Property("CustomActionData")
        WindowsFirewallRemoveApp fwProfile, PathToiTunesExe
        Set fwProfile = Nothing
    End If
End Sub

Sub InitInstallOptionsCheckboxes
    Const msiEvaluateConditionTrue = 1

    If Session.EvaluateCondition("DESKTOP_SHORTCUTS=""1""") = msiEvaluateConditionTrue Then Session.Property("ChkOptShortcuts") = "1"
    If Session.EvaluateCondition("MEDIA_DEFAULTS=""1""") = msiEvaluateConditionTrue Then Session.Property("ChkOptDefPlayer") = "1"
    Session.Property("ChkOptInstASU") = "1"
End Sub

Sub InitFinishCheckbox
    Const msiRunModeRebootAtEnd = 6
    Const msiEvaluateConditionTrue = 1

    If Not Session.Mode(msiRunModeRebootAtEnd) Then
        Session.Property("ChkOptLaunchiTunes") = "1"
        Session.Property("ShowChkOptLaunchiTunes") = "1"
    Else
        Session.Property("ChkOptLaunchiTunes") = ""
        Session.Property("ShowChkOptLaunchiTunes") = ""
    End If
End Sub

Sub TerminateiTunesProcesses
    Session.Property("TerminateProcessName") = "iTunesHelper"
    Session.DoAction "TerminateProcessAction"
End Sub

Sub AddDesktopShortcuts
    Const msiViewModifyInsertTemporary = 7
    Const msidbRemoveFileInstallModeOnRemove = 2
    Dim View
    Dim Record

    Set View = Session.Database.OpenView("SELECT `Shortcut`, `Directory_`, `Name`, `Component_`, `Target`, `Arguments`, `Description`, `Hotkey`, `Icon_`, `IconIndex`, `ShowCmd`, `WkDir` FROM `Shortcut`")
    View.Execute
    Set Record = Session.Installer.CreateRecord(12)
    Record.StringData(1) = "iTunes_Desktop"
    Record.StringData(2) = "DesktopFolder"
    Record.StringData(3) = "iTunes"
    Record.StringData(4) = "iTunes.exe"
    Record.StringData(5) = "iTunes"
    Record.StringData(9) = "iTunesIco.exe"
    Record.IntegerData(10) = 0
    Record.IntegerData(11) = 1

    View.Modify msiViewModifyInsertTemporary, Record

    Record.StringData(1) = "iTunes_QuickLaunch"
    Record.StringData(2) = "QuickLaunchFolder"

    View.Modify msiViewModifyInsertTemporary, Record

    View.Close
    Set Record = Nothing
    Set View = Nothing
End Sub